Accueil > Xcas > Xcas au collège

Xcas au collège

Dernier ajout : 19 juin 2008.

Articles de cette rubrique

    19 juin 2008

  • Patrons dépliables de solides avec Xcas

    Voici quelques exemples de sections de solides faites avec Xcas.

    Dans chacun des cas, ouvrir une session geo3d et insérer les commandes correspondes.

    Le cube



    (A :=point(0,0,0)),(B :=point(1,0,0)),(C :=point(1,1,0)),(D :=point(0,1,0)),affichage(polygone(A,B,C,D),rouge+rempli),affichage(polygone(A,B,C,D),noir) ;
    assume(a :=[1.57079632679,pi/2,pi,pi/100.0]) ;
    (E :=rotation(droite(D,A),a,B)),(F :=rotation(droite(D,A),a,C)),affichage(polygone(A,D,F,E),bleu+rempli),affichage(polygone(A,D,F,E),noir),(K :=rotation(droite(B,C),a,A)),(L :=rotation(droite(B,C),a,D)),affichage(polygone(B,C,L,K),bleu+rempli),affichage(polygone(B,C,L,K),noir) ;
    assume(b :=[1.57079632679,pi/2,pi,pi/100.0]) ;
    (G :=rotation(droite(A,B),b,D)),(H :=rotation(droite(A,B),b,C)),affichage(polygone(B,A,G,H),jaune+rempli),affichage(polygone(B,A,G,H),noir),(I :=rotation(droite(C,D),b,A)),(J :=rotation(droite(C,D),b,B)),affichage(polygone(C,D,I,J),jaune+rempli),affichage(polygone(C,D,I,J),noir) ;
    assume(c :=[1.88495562,pi/2,pi,pi/100.0]) ;
    (M :=rotation(droite(F,E),c,A)),(N :=rotation(droite(F,E),c,D)),affichage(polygone(E,F,N,M),rouge+rempli),affichage(polygone(E,F,N,M),noir) ;

    JPEG - 63.9 ko

    Le parallélépipède



    (d :=5),(l :=3),(h :=1) ;
    (A :=point(0,0,0)),(B :=point(d,0,0)),(C :=point(d,l,0)),(D :=point(0,l,0)),affichage(polygone(A,B,C,D),rouge+rempli),affichage(polygone(A,B,C,D),noir) ;
    assume(a :=[1.57079632679,pi/2,pi,pi/100.0]) ;
    (E :=rotation(droite(D,A),a,point(h,0,0))),(F :=rotation(droite(D,A),a,point(h,l,0))),affichage(polygone(A,D,F,E),bleu+rempli),affichage(polygone(A,D,F,E),noir),(K :=rotation(droite(B,C),a,point(d-h,0,0))),(L :=rotation(droite(B,C),a,point(d-h,l,0))),affichage(polygone(B,C,L,K),bleu+rempli),affichage(polygone(B,C,L,K),noir) ;
    assume(b :=[1.57079632679,pi/2,pi,pi/100.0]) ;
    (G :=rotation(droite(A,B),b,point(0,h,0))),(H :=rotation(droite(A,B),b,point(d,h,0))),affichage(polygone(B,A,G,H),jaune+rempli),affichage(polygone(B,A,G,H),noir),(I :=rotation(droite(C,D),b,point(0,l-h,0))),(J :=rotation(droite(C,D),b,point(d,l-h,0))),affichage(polygone(C,D,I,J),jaune+rempli),affichage(polygone(C,D,I,J),noir) ;
    assume(c :=[1.88495562,pi/2,pi,pi/100.0]) ;
    (M :=rotation(droite(F,E),c,A)),(N :=rotation(droite(F,E),c,D)),(O :=translation((d-h)/h*vecteur(E,M),M)),(P :=translation((d-h)/h*vecteur(F,N),N)),affichage(polygone(E,F,P,O),rouge+rempli),affichage(polygone(E,F,P,O),noir) ;

    JPEG - 67.5 ko

    La pyramide



    (A :=point(0,0,0)),(B :=point(2,0,0)),(C :=point(2,2,0)),(D :=point(0,2,0)),(S :=point(3,1,4)),(R :=isobarycentre(A,B,C,D)) ;
    affichage(polygone(A,B,C,D),bleu+rempli),affichage(polygone(A,B,C,D),noir) ;
    (O :=projection(plan(A,B,C),S)),(I :=projection(droite(A,B),O)),(J :=projection(droite(B,C),O)),(K :=projection(droite(C,D),O)),(L :=projection(droite(D,A),O)) ;
    assume(t :=[0.1,0,1,0.1]) ;
    (EE :=inter_unique(plan(I,S,O),parallele(R,droite(A,B)))),(FF :=inter_unique(plan(J,S,O),parallele(R,droite(B,C)))),(GG :=inter_unique(plan(K,S,O),parallele(R,droite(C,D)))),(HH :=inter_unique(plan(L,S,O),parallele(R,droite(D,A)))) ;
    (E :=rotation(droite(A,B),t*(pi-angle(I,EE,S)),S)),affichage(polygone(A,B,E),rouge+rempli),affichage(polygone(A,B,E),noir),(F :=rotation(droite(B,C),t*(pi-angle(J,FF,S)),S)),affichage(polygone(B,C,F),rouge+rempli),affichage(polygone(B,C,F),noir),(G :=rotation(droite(C,D),t*(pi-angle(K,GG,S)),S)),affichage(polygone(C,D,G),rouge+rempli),affichage(polygone(C,D,G),noir),(H :=rotation(droite(D,A),t*(pi-angle(L,HH,S)),S)),affichage(polygone(D,A,H),rouge+rempli),affichage(polygone(D,A,H),noir) ;

    JPEG - 38.2 ko

    Le tétraèdre



    (A :=point(0,0,0)),(B :=point(2,0,0)),(C :=point(1,3,0)),(S :=point(-2,1,4)),(R :=isobarycentre(A,B,C)) ;
    affichage(polygone(A,B,C),bleu+rempli),affichage(polygone(A,B,C),noir) ;
    (O :=projection(plan(A,B,C),S)),(I :=projection(droite(A,B),O)),(J :=projection(droite(B,C),O)),(K :=projection(droite(C,A),O)) ;
    assume(t :=[0.0,0,1,0.1]) ;
    (EE :=inter_unique(plan(I,S,O),parallele(R,droite(A,B)))),(FF :=inter_unique(plan(J,S,O),parallele(R,droite(B,C)))),(GG :=inter_unique(plan(K,S,O),parallele(R,droite(A,C)))) ;
    (E :=rotation(droite(A,B),t*(pi-angle(I,EE,S)),S)),affichage(polygone(A,B,E),rouge+rempli),affichage(polygone(A,B,E),noir),(F :=rotation(droite(B,C),t*(pi-angle(J,FF,S)),S)),affichage(polygone(B,C,F),rouge+rempli),affichage(polygone(B,C,F),noir),(G :=rotation(droite(C,A),t*(pi-angle(K,GG,S)),S)),affichage(polygone(A,C,G),rouge+rempli),affichage(polygone(A,C,G),noir) ;

    JPEG - 48.9 ko

  • Sections de solides avec Xcas

    Voici quelques exemples de sections de solides faites avec Xcas.

    Dans chacun des cas, ouvrir une session geo3d et insérer les comandes correspondes.

    Le cube



    affichage(width_point_4) ;
    c :=3 ;
    (A :=point(0,0,0)),(B :=point(c,0,0)),(C :=point(c,c,0)),(D :=point(0,c,0)),(E :=point(0,0,c)),(F :=point(c,0,c)),(G :=point(c,c,c)),(H :=point(0,c,c)) ;
    affichage(polyedre(A,B,C,D,H,G,F,E),rouge+rempli) ;
    plan(x+y+z=7) ;
    affichage(inter(plan(x+y+z=7),polyedre(A,B,C,D,H,G,F,E)),bleu+line_width_4) ;

    JPEG - 86.8 ko

    Le parallélépipède



    affichage(width_point_4) ;
    (L :=3),(l :=2),(h :=3) ;
    (A :=point(0,0,0)),(B :=point(L,0,0)),(C :=point(L,l,0)),(D :=point(0,l,0)),(E :=point(0,0,h)),(F :=point(L,0,h)),(G :=point(L,l,h)),(H :=point(0,l,h)) ;
    affichage(polyedre(A,B,C,D,H,G,F,E),rouge+rempli) ;
    affichage(plan(z=1),noir+line_width_2) ;
    affichage(inter(plan(z=1),polyedre(A,B,C,D,H,G,F,E)),bleu+line_width_4) ;

    JPEG - 64.7 ko

    Le prisme droit



    affichage(width_point_4) ;
    h :=5 ;
    (A :=point(0,0,0)),(B :=point(4,0,0)),(C :=point(4,1,0)),(D :=point(2,1,0)),(E :=point(2,5,0)),(F :=point(0,5,0)) ;
    affichage(prisme([A,B,C,D,E,F],[0,0,h]),rouge+rempli) ;
    (A_1 :=translation([0,0,h],A)),(B_1 :=translation([0,0,h],B)),(C_1 :=translation([0,0,h],C)),(D_1 :=translation([0,0,h],D)),(E_1 :=translation([0,0,h],E)),(F_1 :=translation([0,0,h],F)) ;
    affichage(plan(z=4),noir+line_width_2) ;
    affichage(inter(plan(z=4),prisme([A,B,C,D,E,F],[0,0,h])),bleu+line_width_4) ;

    JPEG - 78.9 ko

    La sphère



    affichage(width_point_4) ;
    r :=4 ;
    O :=point(0,0,0) ;
    affichage(sphere(O,r),rouge+rempli) ;
    affichage(plan(z=2),noir+line_width_2) ;
    affichage(inter(plan(z=2),sphere(O,r)),bleu+line_width_4) ;

    JPEG - 69.5 ko

    Le cylindre



    affichage(width_point_4) ;
    (r :=4),(h :=5) ;
    O :=point(0,0,0) ;
    affichage(cylindre(O,[0,0,1],r,h),rouge+rempli) ;
    affichage(plan(z=2),noir+line_width_2) ;
    affichage(inter(plan(z=2),[cylindre(O,[0,0,1],4,5)]),bleu+line_width_4) ;

    JPEG - 69 ko

    Le cône



    affichage(width_point_4) ;
    (a :=pi/4),(h :=5) ;
    S :(point(0,0,h)) ;
    affichage(demi_cone(S,[0,0,-1],a,h),rouge+rempli) ;
    affichage(plan(z=2),noir+line_width_2) ;
    affichage(inter(plan(z=2),[demi_cone(S,[0,0,-1],a,h)]),bleu+line_width_4) ;

    JPEG - 68 ko

    La pyramide



    affichage(width_point_4) ;
    (c :=4),(h :=5) ;
    (A :=point(0,0,0)),(B :=point(c,0,0)),(C :=point(c,c,0)),(D :=point(0,c,0)),(S :=point(c/2,c/2,h)) ;
    affichage(polyedre(A,B,C,D,S),rouge+rempli) ;
    affichage(plan(z=3),noir+line_width_2) ;
    affichage(inter(plan(z=3),polyedre(A,B,C,D,S)),bleu+line_width_4) ;

    JPEG - 83.9 ko

  • 6 juin 2008

  • Géométrie analytique au collège avec Xcas

    Voici comment on peut résoudre un exercice classique de géométrie analytique.

    Enoncé


    Dans un repère orthonormé (O,I,J), on donne les points suivants :

    A(1~;~2) \qquad B(-2\sqrt{3}~;~\sqrt{3}) \qquad C(-1~;~-2)

    1) Faire une figure.

    2) Montrer que ABC est un triangle équilatéral.

    Résolution à l’aide de Xcas


    1) Faire une figure.

    Dans une session Xcas, on ajoute une fenêtre de géométrie 2D :

    Menu Editer ---> Ajouter —> geo2d exact

    On crée ensuite les points et le triangle en plaçant les commandes à gauche de la fenêtre graphique.

    A:=point(1,2) ;
    B:=point(-2*sqrt(3),sqrt(3)) ;
    C:=point(-1,-2) ;
    triangle(A,B,C) ;

    JPEG - 20.3 ko

    2) Montrer que ABC est un triangle équilatéral.

    On calcule successivement les longueurs en plaçant les instructions en dessous de la fenêtre graphique :

    normal(longueur(A,B))

    2~\sqrt{5}

    normal(longueur(A,C))

    2~\sqrt{5}

    normal(longueur(B,C))

    2~\sqrt{5}


  • 4 mai 2008

  • Diagrammes en bâtons et camembert avec Xcas

    Voici comment on peut résoudre un exercice classique sur les diagrammes eb bâtons et les camemberts.

    Enoncé


    Voici le répartition des supporters parmi un groupe de 50 personnes de São Paulo :

    Clubs Santos São Paulo FC Palmeiras Corinthians
    Nombre de supporters 5 15 20 10

    1) Calculer les fréquences correspondantes.

    2) Tracer le diagramme en bâtons correspondant.

    3) Tracer le camembert correspondant. On donnera les valeurs des différents angles.

    Résolution à l’aide de Xcas


    X:=["Santos","São Paulo FC","Palmeiras","Corinthians"]

    [\mbox{Santos},\mbox{São Paulo FC},\mbox{Palmeiras},\mbox{Corinthians}]

    Effectifs:=[5,15,20,10]

    [5,15,20,10]

    1) Calculer les fréquences correspondantes.

    frequences(X,E):={
    local n,N,M,j;
    n:=size(E);
    N:=sum(E);
    M:=matrix(3,n+2);
    M[0,0]:="----------";
    M[1,0]:="Effectifs";
    M[2,0]:="Fréquences (en %)";
    M[0,n+1]:="Total";
    M[1,n+1]:=N;
    M[2,n+1]:=100.0;
    for (j:=1;j<=n;j:=j+1)
     {M[0,j]:=X[j-1];
      M[1,j]:=E[j-1];
      M[2,j]:=evalf(E[j-1]/N*100);
     }
    return M;
    }
    :;

    // Parsing frequences

    // Success compiling frequences

    frequences(X,Effectifs)

    \left[\begin{array}{cccccc}
\mbox{----------} & \mbox{Santos} & \mbox{Sao Paulo FC} & \mbox{Palmeiras} & \mbox{Corinthians} & \mbox{Total} \\
\mbox{Effectifs} & 5 & 15 & 20 & 10 & 50 \\
\mbox{Frequences (en \%)} &     10.0 &     30.0 &     40.0 &     20.0 &    100.0
\end{array}\right]

    2) Tracer le diagramme en bâtons correspondant.

    diagramme_batons(X,Effectifs)

    JPEG - 16.3 ko

    3) Tracer le camembert correspondant. On donnera les valeurs des différents angles.

    angles(X,E):={
    local n,N,M,j;
    n:=size(E);
    N:=sum(E);
    M:=matrix(3,n+2);
    M[0,0]:="----------";
    M[1,0]:="Effectifs";
    M[2,0]:="Angles (en degrés)";
    M[0,n+1]:="Total";
    M[1,n+1]:=N;
    M[2,n+1]:=360.0;
    for (j:=1;j<=n;j:=j+1)
     {M[0,j]:=X[j-1];
      M[1,j]:=E[j-1];
      M[2,j]:=evalf(E[j-1]/N*360);
     }
    return M;
    }
    :;

    // Parsing angles

    // Success compiling angles

    angles(X,Effectifs)

    \left[\begin{array}{cccccc}
\mbox{----------} & \mbox{Santos} & \mbox{Sao Paulo FC} & \mbox{Palmeiras} & \mbox{Corinthians} & \mbox{Total} \\
\mbox{Effectifs} & 5 & 15 & 20 & 10 & 50 \\
\mbox{Angles (en degres)} &     36.0 &    108.0 &    144.0 &     72.0 &    360.0
\end{array}\right]

    camembert(X,Effectifs)

    JPEG - 31.1 ko

  • 28 avril 2008

  • Résolution de systèmes linéaires avec Xcas

    Voici comment on peut résoudre un exercice classique sur les systèmes de deux équations à deux inconues.

    Enoncé


    Résoudre le système

    
\left\{
  \begin{array}[l]{rcr@{\quad = \quad}c}
    3x & - & 2y  & 3\\
    5x & + & y & 7\\
  \end{array}
\right.

    Résolution à l’aide de Xcas


    resoudre_systeme_lineaire([3*x-2*y=3,5*x+y=7],[x,y])

    \left[ {{17}\over{13}} \quad {{6}\over{13}} \right]


0 | 5